﻿title   ZOBEX HD Disk Controller Test Program (14-Sep-81)
;########################################################;
;#                                                      #;
;#      DISK TEST PROGRAM FOR ZOBEX HD CONTROLLER       #;
;#                                                      #;
;########################################################;


;########################################################;
;#              SYSTEM DEFINITIONS                      #;
;########################################################;


;       external references:


        global  boot            ; CP/M reboot vector adr
        global  sedtbl          ; table of track random number seeds
        global  stktop          ; initial stack setting
        global  buf0            ; data buffer 0
        global  buf1            ; data buffer 1


;       Entry points:


        entry   start           ; start of program
        entry   drive           ; current drive no
        entry   scyl            ; current starting cylinder adr
        entry   ecyl            ; current ending cylinder adr


;       Assembly options:


DEBUG   equ     0               ; assemble debugging code if <> 0


;       misc definitions:


MAXCYL  equ     174             ; maximum cylinder number
MAXSEC  equ     53              ; maximum sector number
POLY8   equ     5fh             ; 8 bit polynomial used for random numbers
RATE    equ     0000b           ; step rate is initially 10 usec
WPVAL   equ     77/4            ; first cylinder requiring write precomp
HDBASE  equ     80h             ; base of I/O ports for HD controller


;       Structure definitions:


        struct  0
ERRMSK: defs    1               ; error mask byte
ERRLOC: defs    2               ; pointer to error counter cell
ERRSTR: defs    2               ; pointer to error msg string
ERBSIZ: defs    0
        endm


        list    off
*include stddefs.z80            ; library definition files
*include wd1000.z80             ; WD1000 definitions
*maclib  stdmacs.z80            ; library macro routines
        list    on




;########################################################;
;#           USER DEFINABLE PARAMETER AREA              #;
;########################################################;


drive:  defb    0               ; current drive no (initially A)
scyl:   defb    0               ; current starting cylinder adr
ecyl:   defb    MAXCYL          ; current ending cylinder adr
mxhead: defb    7               ; maximum head number




;########################################################;
;#                   MAIN PROGRAM                       #;
;########################################################;


start:  tstz80                  ; CPU must be Z-80
        ld      sp,stktop
        print   'ZOBEX Hard Disk Test Utility V1.00  (Created 14-Sep-81)',CR,LF
        call    init
more:   ld      sp,stktop       ; reset stack
        call    menu            ; print menu
        call    getcmd          ; get cmd from user
        call    (hl)            ; call (hl)
        br      more            ; do this again




init:   ; Perform initialization for disk test program
        ;
        ld      hl,(boot+1)
        ld      (wsadr),hl      ; save warm boot adr at wsadr
        ld      hl,more
        ld      (boot+1),hl     ; and modify vector to xfr to "more"
        ret




menu:   ; Print menu for disk test program
        ;
        print   CR,LF,LF,'Options:'
        print   CR,LF,'  D: Select DISK to test'
        print   CR,LF,'  R: Set cylinder RANGE for subsequent tests'
        print   CR,LF,'  T: Test disk'
        print   CR,LF,'  E: EXIT to CP/M (insert system disk first)'
        print   CR,LF,'Set to test cylinders '
        ld      hl,(scyl)
        ld      h,0
        decout
        print   ' through '
        ld      hl,(ecyl)
        ld      h,0
        decout
        print   ' on drive '
        ld      a,(drive)
        add     '0'
        chrout
        print   CR,LF,'Selection: '
        ret                     ; that's all




getcmd: ; Input and decode user cmd, return ^ to processing routine in hl
        ;
        call    getcon
        ld      hl,ctblnd       ; HL := ^end of cmd code table
        ld      bc,ctblsz       ; BC := number of table entries
        cpdr                    ; search thru table, BC = 0 if no match
        ld      hl,dtbl         ; HL := ^base of dispatch table
        add     hl,bc
        add     hl,bc           ; HL := ^adr of processing routine
        ld      a,(hl)
        inc     hl
        ld      h,(hl)
        ld      l,a             ; HL := adr of processing routine
        ret                     ; done




dtbl:   ; Dispatch table for cmd processing routines
        ;
        defw    badcmd          ; bad cmd
        defw    seldrv          ; select drive for testing
        defw    setrng          ; set cylinder test range
        defw    tst             ; test disk
        defw    exit            ; exit to CP/M




ctbl:   ; Command code lookup table
        ;
        defb    -1              ; token illegal character
        defb    'D'             ; select drive for testing
        defb    'R'             ; set cylinder test range
        defb    'T'             ; test disk
        defb    'E'             ; exit to CP/M
ctblnd  equ     $-1             ; end of this table
ctblsz  equ     $-ctbl          ; size of this table




;########################################################;
;#              COMMAND PROCESSING ROUTINES             #;
;########################################################;


badcmd: ; Process illegal cmds
        ;
        print   BEL,'?Illegal command',CR,LF
        ret




seldrv: ; Select a drive for subsequent testing
        ;
        print   'Select which drive: '
        call    getcon          ; input drive
        sub     a,'0'           ; convert, qualify drive code
        cp      a,'3'+1-'0'
        br      nc,baddrv       ; bad drive code
        ld      (drive),a       ; update drive code
        ret
        ;
baddrv: print   BEL,'?Bad drive ID - valid drives are 0 through 3'
        ret




setrng: ; Set range of cylinders to test
        ;
        print   'Starting cylinder: '
        call    getint          ; input starting cylinder
        br      c,badrng
        cp      a,MAXCYL
        br      gt,badrng       ; error if > MAXCYL
        save    af
        print   'Ending cylinder: '
        call    getint          ; input ending cylinder
        restor  bc              ; B := starting cylinder
        br      c,badrng
        cp      a,b
        br      lt,badrng       ; error if < scyl
        cp      a,MAXCYL
        br      gt,badrng       ; error if > MAXCYL
        ld      (ecyl),a
        ld      a,b
        ld      (scyl),a
        ret
        ;
badrng: print   BEL,'?Bad range - must be between 0 and '
        decout  MAXCYL
        ret




tst:    ; Test disk
        ;
        ld      hl,128
        ld      (seclen),hl     ; seclen := 128
        clra
        ld      (ssec),a        ; ssec := 0
        ld      a,MAXSEC
        ld      (esec),a        ; esec := MAXSEC




tstdsk: ; Continuous disk test (aborts if ^C entered)
        ;
        clra
        ld      (head),a        ; head := 0
        call    recal           ; recalibrate, initialize requested disk
        ld      hl,0
        ld      (damtot),hl     ; damtot := 0
        ld      (tr0tot),hl     ; tr0tot := 0
        ld      (abttot),hl     ; abttot := 0
        ld      (idtot),hl      ; idtot := 0
        ld      (critot),hl     ; critot := 0
        ld      (crdtot),hl     ; crdtot := 0
        ld      (bbtot),hl      ; bbtot := 0
        ld      (cmptot),hl     ; cmptot := 0
        ld      (pass),hl       ; pass := 0
        ld      a,(esec)
        ld      hl,ssec
        sub     a,(hl)
        inc     a
        ld      e,a
        ld      d,0
        mulply  (seclen)
        ld      (trklen),hl     ; trklen := (esec-ssec+1) * seclen
        ld      a,1             ; initial seed
td0:    ld      (seed),a        ; update random number seed
        ld      (rand),a        ; set starting random byte
        call    fildsk          ; write test pattern on disk
        call    chkdsk          ; read back looking for same sequence
        call    ptally          ; print tally info
        ld      a,(seed)
        inc     a               ; bmp seed
        br      nz,td0
        inc     a               ; skip zero
        br      td0




exit:   ; Exit to CP/M
        ;
        ld      hl,(wsadr)
        ld      (boot+1),hl     ; restore warm start adr @ boot+1
        rst     0               ; reboot system (hopefully)




;########################################################;
;#              TEST SUPPORT SUBROUTINES                #;
;########################################################;


fildsk: ; Fill disk with random byte sequence starting with (seed)
        ;
        ld      a,(scyl)
fil0:   ld      (cyl),a         ; update cylinder adr
        clra
        ld      (head),a        ; head := 0
fil1:   call    cchk            ; chk for console break
        call    setsdh          ; select disk, head
        call    gseed           ; HL := ^seed storage for this cylinder, head
        ld      a,(rand)        ; get last random byte generated..
        ld      (hl),a          ; ..and save in table of cylinder seeds
        ld      hl,buf0
        save    hl
        call    genrnd          ; generate 1 track's random data in buf0
        restor  hl
        call    puttrk          ; write the data
        ld      hl,head
        inc     (hl)            ; head := head + 1
        ld      a,(mxhead)
        cp      a,(hl)
        br      ge,fil1         ; repeat 'til head > mxhead
        ld      a,(cyl)
        call    gencyl          ; generate next random cylinder adr
        ld      hl,scyl
        cp      a,(hl)
        br      ne,fil0         ; repeat 'til cyl = scyl
        ret




chkdsk: ; Read back disk and check for same random sequence
        ;
        ld      a,(scyl)
        ld      (cyl),a         ; cyl := scyl
ckd0:   clra
        ld      (head),a        ; head := 0
ckd1:   call    cchk            ; chk for console break
        call    setsdh          ; select disk, head
        call    gseed
        ld      a,(hl)          ; A := seed for this cyl, head
        ld      (rand),a        ; update for genrnd
        ld      hl,buf0
        call    genrnd          ; generate random sequence in buf0
        ld      hl,buf1
        call    gettrk          ; read back same sequence from disk
        call    chktrk          ; compare, print errors
        ld      hl,head
        inc     (hl)            ; head := head + 1
        ld      a,(mxhead)
        cp      a,(hl)
        br      ge,ckd1         ; repeat 'til head > mxhead
        ld      hl,cyl
        inc     (hl)            ; cyl := cyl + 1
        ld      a,(ecyl)
        cp      a,(hl)
        br      ge,ckd0         ; repeat 'til cyl > ecyl
        ret




ptally: ; Print error tally information
        ;
        print   CR,LF,'Pass     Comp    DAM     TRK0    ABORT   ID NF   '
        print   'ID CRC Data CRC',CR,LF
        ld      hl,(pass)
        inc     hl              ; pass := pass + 1
        ld      (pass),hl
        decout                  ; print pass #
        chrout  TAB
        decout  (cmptot)        ; print compare error tally
        chrout  TAB
        decout  (damtot)        ; print DAM error tally
        chrout  TAB
        decout  (tr0tot)        ; print tr0 error tally
        chrout  TAB
        decout  (abttot)        ; print aborted cmd tally
        chrout  TAB
        decout  (idtot)         ; print ID not found tally
        chrout  TAB
        decout  (critot)        ; print ID CRC error tally
        chrout  TAB
        decout  (crdtot)        ; print data CRC error tally
        ret




puttrk: ; Write 1 track beginning @ HL out to the disk
        ;
        ld      a,(cyl)
        ld      c,a
        call    setcyl          ; seek to desired cylinder
        ld      a,(ssec)
        ld      (sector),a      ; sector := ssec
ptk0:   save    hl              ; save DMA adr
        ld      a,(sector)
        ld      c,a
        call    setsec          ; set sector adr
        restor  bc              ; BC := current DMA adr
        save    bc
        call    setdma          ; set DMA adr
        call    wrtsec          ; write next sector
        tcall   a,nz,wrterr     ; report any write errors
        ld      hl,sector
        inc     (hl)            ; bmp sector adr
        ld      a,(esec)
        cp      a,(hl)          ; if sector > esec then
        restor  de
        ret     lt              ;    exit
        ld      hl,(seclen)
        add     hl,de           ; compute next DMA adr
        br      ptk0            ; more sectors to do




gettrk: ; Get the current trk into memory starting @ HL
        ;
        ld      a,(cyl)
        ld      c,a
        call    setcyl          ; seek to current cylinder
        ld      a,(ssec)
        ld      (sector),a      ; sector := ssec
gtk0:   save    hl              ; save DMA adr
        ld      a,(sector)
        ld      c,a
        call    setsec          ; set sector adr
        restor  bc              ; BC := current DMA adr
        save    bc
        call    setdma          ; set DMA adr
        call    rdsec           ; read the sector
        tcall   a,nz,rderr      ; report hard read errors
        ld      hl,sector
        inc     (hl)            ; bmp sector adr
        ld      a,(esec)
        cp      a,(hl)          ; if sector > esec then
        restor  de
        ret     lt              ;    exit
        ld      hl,(seclen)
        add     hl,de           ; compute next DMA adr
        br      gtk0            ; more sectors to do




genrnd: ; Generate 1 track's worth of random data @ HL
        ;
        ld      de,(trklen)     ; DE := number of bytes to generate
        ld      c,POLY8         ; C := 8 bit polynomial
        ld      a,(rand)        ; get start for sequence
gr0:    add     a,a             ; left shift a
        br      nc,gr1          ; jif bit 7 was 0
        xor     a,c             ; else adjust with polynomial in c
gr1:    ld      (hl),a          ; store
        inc     hl
        dec     e
        br      nz,gr0
        dec     d
        br      nz,gr0          ; loop
        ld      (rand),a        ; save last random byte generated
        ret




chktrk: ; Compare buf0 and buf1, report any differences
        ;
        clra
        ld      (badsec),a      ; reset last bad sector adr
        ld      hl,(trklen)
        ex      de,hl
        ld      hl,buf1
        ld      bc,buf0
ckt0:   ld      a,(bc)
        cp      a,(hl)
        call    ne,cmperr       ; mismatch, report error
        inc     hl              ; bmp ptrs
        inc     bc
        dec     e
        br      nz,ckt0
        dec     d
        br      nz,ckt0         ; looping thru the bfrs
        ret




gencyl: ; Generate next random cylinder adr
        ;
        inc     a               ; form 1..MAXCYL+1
        add     a,a             ; shift left
        br      nc,genc0        ; jif bit 7 was 0
        xor     a,POLY8         ; else xor with polynomial
genc0:  dec     a               ; form 0..MAXCYL
        ld      hl,ecyl
        cp      a,(hl)
        br      gt,gencyl       ; generate another if > ecyl
        ld      hl,scyl
        cp      a,(hl)
        br      lt,gencyl       ; generate another if < scyl
        ret




gseed:  ; Return pointer to seed storage cell for current cylinder, head
        ;
        ld      hl,(cyl)
        ld      h,0
        ld      de,(mxhead)
        ld      d,h
        inc     de
        mulply
        ld      de,(head)
        ld      d,0
        add     hl,de
        ld      de,sedtbl
        add     hl,de           ; HL := sedtbl + (mxhead+1) * cyl + head
        ret




cmperr: ; Report compare errors
        ;
        save    hl,de,bc
        ld      de,buf1         ; figure out which sector had mismatch
        dsub    hl,de
        ex      de,hl
        ld      hl,(seclen)
        ex      de,hl
        divide
        ld      a,l
        ld      hl,ssec
        add     a,(hl)          ; A := sector number
        ld      hl,badsec       ; HL := ^last bad sector storage
        cp      a,(hl)          ; previous error here?
        ld      (hl),a          ; update in any case
        jp      z,errxit        ; don't report if previous error
        ld      (sector),a      ; update sector for error info
        print   CR,LF,'Compare'
        ld      hl,(cmptot)
        inc     hl              ; cmptot := cmptot + 1
        ld      (cmptot),hl
        jp      errors          ; report error




rderr:  ; Disk hard read error
        ;
        save    hl,de,bc
        print   CR,LF,'Read '
        br      rwerrs




wrterr: ; Disk hard write error
        ;
        save    hl,de,bc
        print   CR,LF,'Write '
        ;
rwerrs: ; Tally read/write error types
        ;
        ld      ix,errtbl
        ld      b,ertbsz
rwer0:  push    bc
        ld      a,(status)
        and     a,(ix+ERRMSK)
        jr      z,rwer4
        ld      l,(ix+ERRLOC)
        ld      h,(ix+ERRLOC+1)
        inc     (hl)
        jr      nz,rwer2
        inc     hl
        inc     (hl)
rwer2:  ld      l,(ix+ERRSTR)
        ld      h,(ix+ERRSTR+1)
        call    putstr
rwer4:  ld      de,ERBSIZ
        add     ix,de
        pop     bc
        djnz    rwer0
        ;
errors: print   ' error at cylinder '
        ld      hl,(cyl)
        ld      h,0
        decout                  ; print cylinder adr
        print   ', head '
        ld      hl,(head)
        ld      h,0
        decout                  ; print head number
        print   ', sector '
        ld      hl,(sector)
        ld      h,0
        decout                  ; print sector adr
        print   ' on drive '
        ld      a,(drive)
        add     a,'0'
        chrout                  ; print drive id
        call    cchk            ; chk for console abort
errxit: restor  bc,de,hl
        ret




getint: ; Input decimal integer from console, convert to binary
        ;
        call    getlin          ; get a line from console
        ret     c               ; null line
        skipbl  ibuf+2          ; scan past leading blanks
        save    de
        alldig                  ; chk if valid number string
        restor  de
        ret     c               ; not valid
        decin                   ; convert to binary
        clrcf
        ret




getcon: ; Input a line from the console and return the first
        ; non-blank character in the line.  This character is
        ; folded to upper case alfa.  Returns NULL if the line
        ; was empty.
        ;
        call    getlin          ; get a line from console
        skipbl  ibuf+2          ; scan past leading blanks
        ld      a,(de)
        call    foldch
        ret




getlin: ; Input a line from the console into ibuf
        ;
        fill    ibuf,ibuf+21    ; clear input buffer to zeroes
        input   ibuf,20         ; input a line
        save    af
        ld      a,LF
        chrout                  ; issue linefeed to console
        restor  af
        ret




cchk:   ; Chk for ^C, abort if found
        ;
        charst                  ; chk if char avail
        tret    a,z             ; none avail
        charin
        cp      a,ctlc
        ret     ne              ; ignore if char <> ctlc
        print   '^C',CR,LF      ; print message, exit to cmd level
        jp      more




foldch: ; Convert character in reg A to upper case
        ;
        cp      a,'a'
        ret     lt
        cp      a,'z'
        ret     gt
        sub     a,'a'-'A'
        ret




indexa: ; Index HL by A
        ;
        add     a,l
        ld      l,a
        ret     nc              ; done if no cy
        inc     h
        ret




putstr: ; Output string to console til char with bit 7 set
        ;
        ; Entry:   HL = ^ string
        ; Exit:    nil
        ; Alters:  A, HL
        ;
        ld      a,(hl)
        and     a,7fh
        save    hl
        chrout
        restor  hl
        bit     7,(hl)
        inc     hl
        jr      z,putstr
        ret


        form
;########################################################;
;#                 DISK PRIMITIVES                      #;
;########################################################;


recal:  ; Recalibrate disk drive
        ;
        clra
        ld      (head),a
        call    setsdh          ; select drive, head, sector size
        ld      a,WPVAL
        out     (HDWPC),a       ; init write precomp
        ld      a,HDHOMC | 1111b
        out     (HDCSR),a       ; issue slow recalibrate cmd to get to cyl 0
        call    sekwat          ; wait for seek complete
        ld      a,HDHOMC | RATE
        out     (HDCSR),a       ; do another recalibrate cmd to set proper rate
        call    sekwat          ; wait for seek complete
        ret




setsec: ; Set sector number
        ;
        ; entry parms:  C = desired sector number
        ; return parms: none
        ; regs altered: A
        ;
        ld      a,c
        out     (HDSEC),a       ; sector request issued
        ret




setdma: ; Set DMA buffer address
        ;
        ; entry parms:  BC = DMA buffer address
        ; return parms: none
        ;
        ld      (dmaadr),bc     ; save requested DMA buffer adr
        ret




setcyl: ; Set cylinder address
        ;
        ; entry parms:  C = desired cylinder address
        ; return parms: none
        ; regs altered: A
        ;
        ld      a,c
        out     (HDCYLL),a
        clra
        out     (HDCYLH),a
        ret




wrtsec: ; Write disk sector
        ;
        ; entry parms:  none
        ; return parms: A = 0 if no error, 1 if error
        ; regs altered: A, BC, DE, HL
        ;
        call    setsdh          ; select drive, head
        ld      bc,128<<8 | HDDAT
        ld      hl,(dmaadr)
        ld      a,HDWRTC
        out     (HDCSR),a       ; issue write cmd
        call    drqwat          ; wait for DRQ
        otir                    ; fill buffer
        call    bsywat          ; wait for write to complete
        jr      rwxit           ; test for errors, exit




rdsec:  ; Read disk sector
        ;
        ; entry parms:  none
        ; return parms: A = 0 if no error, 1 if error
        ; regs altered: A, BC, DE, HL
        ;
        call    setsdh          ; select drive, head
        ld      a,HDRDC
        out     (HDCSR),a       ; issue read cmd
        call    bsywat          ; wait for read to complete
        ld      bc,128<<8 | HDDAT
        ld      hl,(dmaadr)
        inir                    ; empty buffer
rwxit:  in      a,(HDCSR)
        and     a,1<<HERRB      ; test for errors
        ret     z               ; exit if none
        push    af
        in      a,(HDERR)
        ld      (status),a      ; else save error bits
        pop     af
        ret




drqwat: ; Wait for DRQ
        ;
        in      a,(HDCSR)
        bit     DRQB,a
        br      z,drqwat
        ret




sekwat: ; Wait for seek to complete
        ;
        call    bsywat
sekw0:  in      a,(HDCSR)
        bit     SEKCB,a
        jr      z,sekw0
        ret




setsdh: ; Set sector size, drive and head number
        ;
        ; Entry:   drive = drive #, head = head #
        ; Exit:    nil
        ; Altered:
        ;
        ld      a,(drive)       ; A := drive #
        add     a,a             ; shift drive bits into position
        add     a,a
        add     a,a
        ld      hl,head
        or      a,(hl)          ; or in head select bits
        or      a,SSZ128        ; set sector size code
        out     (HDSDH),a       ; output to controller
        ret




bsywat: ; Wait for HDC to complete a command.
        ;
        ; Entry parms:  none
        ; Return parms: none
        ; Regs altered: A
        ;
        ex      (sp),hl
        ex      (sp),hl         ; delay for busy to be set
        save    hl,de
        ld      hl,0
        ld      e,6             ; timeout ctr := 60000h
bsyw0:  call    bsycnt          ; update timeout ctr
        br      c,bsyw2         ; time-out error exit
        in      a,(HDCSR)       ; read controller status
        add     a,a             ; CY := bsy bit
        br      c,bsyw0         ; bsy
        restor  de,hl
        ret
        ;
bsyw2:  ; Process WD1000 timeout condition.
        print   BEL,CR,LF,'Controller timeout error, aborting.'
        jp      more




bsycnt: ; Decrement HDC timeout ctr, return CY set if timeout
        ;
        dec     hl
        tret    hl,nz
        dec     e
        ret     nz
        scf
        ret




hex16:  ; Print contents of HL in hex at console
        ;
        save    hl
        ld      a,h
        hexout
        restor  hl
        ld      a,l
        hexout
        ret




;########################################################;
;#                      TABLES                          #;
;########################################################;


;       Table of error blocks:


errtbl  equ     $
        defb    1<<DAMNFD       ; data address mark not found
        defw    damtot,damstr
        defb    1<<TR0ERR       ; track 0 error
        defw    tr0tot,tr0str
        defb    1<<CMDABT       ; aborted command
        defw    abttot,abtstr
        defb    1<<IDNFD        ; ID not found
        defw    idtot,idstr
        defb    1<<CRCEID       ; CRC error - ID field
        defw    critot,cristr
        defb    1<<CRCED        ; CRC error - data field
        defw    crdtot,crdstr
        defb    1<<BADBLK       ; bad block detected
        defw    bbtot,bbstr
ertbsz  equ     [$-errtbl]/ERBSIZ


;       Error type strings:


damstr: defm    'DAM not found'
tr0str: defm    'Trk 0'
abtstr: defm    'Cmd abort'
idstr:  defm    'ID not found'
cristr: defm    'ID field CRC'
crdstr: defm    'Data field CRC'
bbstr:  defm    'Bad block'




;########################################################;
;#                LOCAL DATA AREA                       #;
;########################################################;


badsec: defs    1               ; storage for last bad sector
dmaadr: defs    2               ; current DMA buffer adr
ibuf:   defs    22              ; console input buffer
ssec:   defs    1               ; starting sector number
esec:   defs    1               ; ending sector number
pass:   defs    2               ; current pass no
rand:   defs    1               ; storage for last random byte generated
seclen: defs    2               ; sector length
sector: defs    1               ; current sector adr
seed:   defs    1               ; storage for random number seed
head:   defs    1               ; current head number
status: defs    1               ; last read/write status from WD1000
cyl:    defs    1               ; current cyl adr
trklen: defs    2               ; track length
wsadr:  defs    2               ; warm start adr (picked up from loc boot+1)


;       error info:


damtot: defs    2               ; total number of DAM not found errors
tr0tot: defs    2               ; total number of track 0 errors
abttot: defs    2               ; total number of aborted commands
idtot:  defs    2               ; total number of ID not found errors
critot: defs    2               ; total number of CRC errors - ID field
crdtot: defs    2               ; total number of CRC errors - data field
bbtot:  defs    2               ; total number of bad blocks detected
cmptot: defs    2               ; total number of compare errors


        end     start